『SMRでした』 東芝 MQ04ABF100 [1TB 7mm] bs029さんのレビュー・評価

[bs029]

2018年5月13日 14:33 [1127550-1]

満足度	3

読込速度	5
書込速度	3
転送速度	無評価
静音性	3
耐久性	無評価

SMRでした

100GiBのファイルへの128KiB Random Writeテストを実行した所、書き込み量が増えるにつれ速度が下がり、書き込み量11GBあたりから1IOPSしか出なくなりました。
更にテスト終了後もMediaCache(ランダムライト用一時領域)を空ける為か内部動作音が止まらず、高消費電力状態が1時間も続きました。
確実にSMRです。

このシーケンシャル速度と価格でCMR(非SMR)だったら文句なしでしたが、SMRなのでオススメまではしづらいです。

最後に、ランダムライトテストでSMRか調べる手法が周知されていないので、そういうバッチファイルを作りました。
使い方は
set diskspd=
にCrystalDiskMark5以降に含まれるdiskspd.exeのフルパスを、
set testfile=
に書き込みテストをする場所を指定してコマンドプロンプトから実行すればOKです。
管理者権限で実行するとファイル内容初期化をスキップする分早いです。

---------- ここから
@echo off
setlocal enabledelayedexpansion
set diskspd=C:\Program Files\CrystalDiskMark5_1_0\CdmResource\diskspd\diskspd64.exe
set testfile=D:\testfile.tmp
set testfilesize=100G
set blocksize=128K
set second=5
set loop=120

echo testfilesize: %testfilesize%
echo blocksize: %blocksize%
echo second: %second%
echo loop: %loop%

set blocksizeB=%blocksize%
if /I "%blocksize:~-1%"=="K" set /A blocksizeB=%blocksize:~0,-1% * 1024
if /I "%blocksize:~-1%"=="M" set /A blocksizeB=%blocksize:~0,-1% * 1024 * 1024
echo テスト用ファイル作成開始 %time%
"%diskspd%" -b%blocksize% -d1 -o1 -t1 -W0 -r -S -w0 -c%testfilesize% "%testfile%">nul
echo テスト用ファイル作成終了 %time%
timeout /T 60 /NOBREAK
echo テスト開始 %time%

for /L %%I in (1, 1, %loop%) do (
"%diskspd%" -b%blocksize% -d%second% -o1 -t1 -W0 -r -S -w100 "%testfile%">nul
set /A speedKB=!ERRORLEVEL! / 10
set /A speedMB=speedKB / 1000
set /A speedMB2=speedKB %% 1000 / 100
set /A totalwriteMB+=speedMB * second
set /A iops=speedKB * 1000 / blocksizeB
echo %%I回目 %second%秒 !speedMB!.!speedMB2!MB/s !iops!iops 累積!totalwriteMB!MB
)

echo テスト終了 %time%
del "%testfile%"
pause
---------- ここまで